$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$!   This command file assists in configuring and running the
$!   gss-server and gss-client test images.  Global symbols
$!   gserver and gclient are used to keep DCL from complaining about
$!   the embedded '-'.
$!
$!   Usage: 
$!       $ @setup [ KDC [CLEAN]  <nodename> ]
$!
$!       - Using setup with no parameters simply defines the global symbols
$!         for gss-server and gss-client.
$!       - [KDC] requests that the sample/node principal be set up in the
$!         local KDC along with its keytab entry.  Both are required.
$!       - [KDC [CLEAN] ] removes the keytab and principal from the local KDC.
$!       - When KDC is used, nodename must be specified for the client principal.
$!
$ if (p1 .eqs. "KDC")
$ then
$     if (p2 .eqs. "CLEAN")
$     then
$        if (p3 .eqs. "")
$        then
$            write sys$output "SETUP-F-NoNodeName, A client nodename (P3) is required for the principal."
$            exit
$        endif
$        @[-]setup_principal KDC CLEAN 'p3
$     else
$         if (p2 .eqs. "")
$         then
$             write sys$output "SETUP-F-NoNodeName, A client nodename (P2) is required for the principal."
$             exit
$         endif
$         @[-]setup_principal KDC 'p2
$     endif
$ else
$     write SYS$OUTPUT "------------ Setup ----------------------------------------"
$     write SYS$OUTPUT "SETUP-I-INFO, setup_principal.com is run ONE time for all the "
$     write sys$output "              MIT sample applications."
$     write SYS$OUTPUT "SETUP-I-INFO, You can do this now, if necessary, or use"
$     write sys$output "              @setup KDC
$     write SYS$OUTPUT "------------ Running the example --------------------------"
$ endif
$!------------------------------------------------------------------------------
$!  Get the local system's architecture type.  F$GETSYI returns either "VAX"
$!  or "Alpha".
$!------------------------------------------------------------------------------
$!
$ cur_dir = F$ENVIRONMENT ("DEFAULT")
$ arch_name = F$GETSYI ("ARCH_NAME")
$ image = "$" + cur_dir - "]" + ".''arch_name']" + "gss-server.exe;"
$ gserver :== 'image
$ image = "$" + cur_dir - "]" + ".''arch_name']" + "gss-client.exe;"
$ gclient :== 'image
$
$ write sys$output "  Run the server as follows:"
$ write sys$output "      $ gserver sample"
$ write sys$output "
$ write sys$output "  Run the client as follows:"
$ write sys$output "      $ gclient servernode sample ""Your message"" "
$ exit