$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$!  This command file sets up the symbols you will need
$!  to run the sample MIT client and server.
$!
$!  This client and server pair require that the
$!  sample/nodename principal be set up.  You can use
$!  @setup KDC [CLEAN]
$!  to accomplish this initialization and cleanup step.
$!  
$!  These are very simple programs that query the
$!  KDC to see who it is that is sending a request.
$!  The data is packaged back up and returned to the client.
$!  Both client and server exit when complete.
$!
$!
$ if (p1 .eqs. "KDC")
$ then
$     if (p2 .eqs. "CLEAN")
$     then
$        if (p3 .eqs. "")
$        then
$            write sys$output "SETUP-F-NoNodeName, A client nodename (P3) is required for the principal."
$            exit
$        endif
$        @[-]setup_principal KDC CLEAN 'p3
$     else
$         if (p2 .eqs. "")
$         then
$             write sys$output "SETUP-F-NoNodeName, A client nodename (P2) is required for the principal."
$             exit
$         endif
$         @[-]setup_principal KDC 'p2
$     endif
$ else
$     write SYS$OUTPUT "------------ Setup ----------------------------------------"
$     write SYS$OUTPUT "SETUP-I-INFO, setup_principal.com is run ONE time for all the "
$     write sys$output "              MIT sample applications."
$     write SYS$OUTPUT "SETUP-I-INFO, You can do this now, if necessary, or use"
$     write sys$output "              @setup KDC
$     write SYS$OUTPUT "------------ Running the example --------------------------"
$ endif
$
$!------------------------------------------------------------------------------
$!  Get the local system's architecture type.  F$GETSYI returns either "VAX"
$!  or "Alpha".
$!------------------------------------------------------------------------------
$!
$ cur_dir = F$ENVIRONMENT ("DEFAULT")
$ arch_name = F$GETSYI ("ARCH_NAME")
$ image = "$" + cur_dir - "]" + ".sserver.''arch_name']" + "sserver.exe;"
$ sserver :== 'image
$ image = "$" + cur_dir - "]" + ".sclient.''arch_name']" + "sclient.exe;"
$ sclient :== 'image
$
$ write sys$output "  Run the server as follows:"
$ write sys$output "      $ sserver -p 1024"
$ write sys$output "
$ write sys$output "  Run the client as follows:"
$ write sys$output "      $ sclient servernode 1024
$exit