$	Verify_state = f$verify ( 0 )
$
$	debug = "''p1'"
$
$	Set noon
$	Exit_status = 4
$	Current_dir = f$trnlnm ( "sys$disk" ) + f$directory ( )
$	Com_proc = f$environment ( "procedure" )
$	New_dir = f$parse ( com_proc, , , "device", "no_conceal" ) + f$parse ( com_proc, , , "directory", "no_conceal" ) - "]["
$
$	call build_it sys$examples:lavc$failure_analysis.mar 'debug'
$	call build_it sys$examples:lavc$start_bus.mar 'debug'
$	call build_it sys$examples:lavc$stop_bus.mar 'debug'
$
$	Exit_status = 1
$
$build_it: SUBROUTINE
$
$	file = "''p1'"
$	debug = "''p2'"
$
$	If f$length ( debug ) .ne. 0 then debug = "/debug "
$	If f$length ( file ) .eq. 0
$	Then
$		Write sys$output "    Please specify file name as P1"
$		Goto done
$	Endif
$	File_spec = f$parse ( file, , , "device" ) + f$parse ( file, , , "directory" ) + -
		    f$parse ( file, , , "name" ) + f$parse ( file, , , "type" ) + f$parse ( file, , , "version" )
$	File_name = f$parse ( file, , , "name" )
$
$!		Set the correct environment for the build.
$!
$	Set verify
$	If f$search ( "''file_name'.log;-1" ) .nes. "" then purge /log 'file_name'.log
$
$!		Build the specified module.
$!
$	If f$search ( "''file_name'.lis" ) .nes. "" then delete /log 'file_name'.lis;*
$	If f$search ( "''file_name'.obj" ) .nes. "" then delete /log 'file_name'.obj;*
$	If f$search ( "''file_name'.map" ) .nes. "" then delete /log 'file_name'.map;*
$	If f$search ( "''file_name'.exe" ) .nes. "" then delete /log 'file_name'.exe;*
$	On warning then goto done
$
$	Macro /debug /list='file_name'.lis /obj='file_name'.obj -
		sys$library:arch_defs.mar+'file_spec'+sys$library:lib.mlb/lib
$	Link 'debug'/map /full /cross /exe='file_name'.exe 'file_name'.obj
$
$ENDSUBROUTINE
$
$ Done:
$	Set noon
$	Temp_verify = f$verify ( verify_state )
$
$	Exit 'exit_status'