$!-----------------------------------------------------------------------------
$! BUILD_PROXYMUNGE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == SSL then build for SSL
$!
$! 30-JUL-2020  MGD  broaden to include VSI SSL111 (what a munge!)
$! 23-FEB-2020  MGD  adapt to OpenSSL 1.1.n and later (WASD OpenSSL only)
$! 22-SEP-2007  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ on controly then exit 44
$!
$ @wasd_root:[src]archer.com "PROXYMUNGE"
$!
$ p1 = f$edit(p1,"upcase")
$!
$ if P2 .eqs. "SSL"
$ then
$    if f$trnlnm("WASD_SSLROOT","LNM$PROCESS") .eqs. ""
$    then
$       @wasd_root:[install]ssl_detect
$       if f$length(f$trnlnm("WASD_SSLROOT","LNM$PROCESS")) .le. 1 then P2 = ""
$    endif
$ endif
$ munge_via_ssl = "MUNGE_VIA_SSL=0"
$ if P2 .eqs. "SSL" then munge_via_ssl = "MUNGE_VIA_SSL=1"
$!
$ build_datetime = "BUILD_DATETIME=""""""""""""" +-
                   f$extract(0,10,f$cvtime()) + ":" +-
                   f$extract(11,8,f$cvtime()) + """"""""""""""
$!
$ defines = " /define=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE," +-
                       "''BUILD_DATETIME',''munge_via_ssl')"
$!
$ includes = " /include=[-.misc]"
$ warnings=  " /warning=(disable=(preoptw,implicitfunc," +-
                         "needconstext,addrconstext))"
$!
$ cc_options = "/decc /optimize /stand=relaxed /prefix=all /names=as_is" +-
               includes + defines + warnings
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    set verify
$    cc 'cc_options' /object='object_dir' proxymunge
$!   'f$verify(0)
$    set on
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    cgilib_olb = "[src.misc.obj_''wasd_arch_name']cgilib.olb"
$    if P2 .eqs. "SSL" 
$    then
$       set verify
$ link /executable=wasd_exe:proxymunge.exe -
  [.obj_'wasd_arch_name']proxymunge,-
  'cgilib_olb'/library,-
  'f$trnlnm("WASD_LIBSSL")',-
  'f$trnlnm("WASD_LIBCRYPTO")'
$!      'f$verify(0)
$    else
$       set verify
$ link /executable=wasd_exe:proxymunge.exe -
  [.obj_'wasd_arch_name']proxymunge,-
  'cgilib_olb'/library
$!      'f$verify(0)
$    endif
$ endif
$ purge /nolog 'object_dir'
$!
$!-----------------------------------------------------------------------------