$!-----------------------------------------------------------------------------
$! BUILD_GEOLOCATE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == OBJECT to build object module
$! P3 == SSL to build TLS-capable
$!
$! 18-MAR-2022  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ on controly then exit 44
$ on error then continue
$!
$ @wasd_root:[src]archer.com "GEOLOCATE"
$!
$ p1 = f$edit(p1,"upcase")
$ p2 = f$edit(p2,"upcase")
$ p3 = f$edit(p3,"upcase")
$!
$ build_datetime = "BUILD_DATETIME=""""""""""""" +-
                   f$extract(0,10,f$cvtime()) + ":" +-
                   f$extract(11,8,f$cvtime()) + """"""""""""""
$!
$ defines = " /define=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE," +-
                       "''BUILD_DATETIME')"
$!
$ if p2 .eqs. "OBJECT"
$ then
$    defines = defines - ")" + ",GEOLOCATE_OBJECT)"
$    object = "_OBJECT"
$ else
$    object = ""
$ endif
$!
$!(currently GeoLocate does not use any secure services)
$ if p3 .eqs. "SSL"
$ then
$    @wasd_root:[install]ssl_detect
$    if f$length(f$trnlnm("WASD_SSLROOT","LNM$PROCESS")) .gt. 1
$    then
$       defines = defines - ")" + ",GEOLOCATE_OPENSSL)"
$       define /user /process openssl 'f$trnlnm("WASD_OPENSSL","lnm$process")'
$    endif
$ endif
$!
$ includes = " /include=[src.misc]"
$ warnings=  " /warning=(disable=(preoptw,implicitfunc," +-
                                  "needconstext,addrconstext))"
$!
$ cc_options = "/decc /optimize /stand=relaxed /prefix=all /names=as_is" +-
               includes + defines + warnings
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    set verify
$ cc 'cc_options' /object='object_dir'geolocate'object' geolocate
$!   'f$verify(0)
$    set on
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    cgilib_olb = "[src.misc.obj_''wasd_arch_name']cgilib.olb"
$    set noon
$    if P3 .eqs. "SSL" .and. -
        f$length(f$trnlnm("WASD_SSLROOT","LNM$PROCESS")) .ge. 1
$    then
$       set verify
$ link /notrace /executable=wasd_exe:geolocate.exe -
  [.obj_'wasd_arch_name']geolocate,-
  'cgilib_olb'/library,-
  'f$trnlnm("WASD_LIBSSL")',-
  'f$trnlnm("WASD_LIBCRYPTO")'
$!      'f$verify(0)
$    else
$       set verify
$ link /notrace /executable=wasd_exe:geolocate.exe -
  [.obj_'wasd_arch_name']geolocate,-
  'cgilib_olb'/library
$!      'f$verify(0)
$    endif
$    set on
$ endif
$!
$!-----------------------------------------------------------------------------