$ !
$ ! File name:      TCPIP$EXTENSION_MIB_STARTUP.COM
$ ! Product:        VSI TCP/IP Services for OpenVMS
$ ! Version:        V6.0-24
$ !
$ ! Copyright 2015, 2024 VMS Software, Inc. and Hewlett Packard          
$ ! Enterprise Development L.P.                                          
$ !                                                                      
$ ! VMS SOFTWARE, INC. CONFIDENTIAL. This software is confidential       
$ ! proprietary software licensed by VMS Software, Inc., and is not      
$ ! authorized to be used, duplicated or disclosed to anyone without     
$ ! the prior written permission of VMS Software, Inc.                   
$ ! Copyright 2015, 2024 VMS Software, Inc.                              
$ !
$ ! HPE CONFIDENTIAL. This software is confidential proprietary software 
$ ! licensed by Hewlett Packard Enterprise Development, LP, and is not   
$ ! authorized to be used, duplicated or disclosed to anyone without the 
$ ! prior written permission of HPE.                                     
$ ! Copyright 2015, 2024 Hewlett Packard Enterprise Development, LP            
$ !                                                                      
$ !
$     set :=
$     set noon
$     set symbol /scope=(nolocal,global)
$     set symbol /scope=(nolocal,noglobal)/verb
$     on control_y then goto exit
$     serv_id	= f$edit("tcpip$snmp","upcase")
$     serv_home	= f$edit("sys$sysdevice:[''serv_id']","upcase")
$ !
$ ! If planning to install one or more images for snmp extension
$ ! subagents (e.g., Chess example), follow the steps below:
$ !
$ ! 1. Copy TCPIP$CHESS_SUBAGENT.EXE from TCPIP$SNMP_EXAMPLES, or
$ !    other images from location where built, to SYS$SYSTEM.
$ !
$ ! 2. Remove or comment out the GOTO below.
$ !
$ ! 3. To install snmp extension subagent images, with or without
$ !    privileges:
$ !
$ !    a. specify privileges as a comma separated list
$ !
$ !    b. replicate the two lines after the "install_subagents"
$ !	  label for each subagent image
$ !
$     goto exit
$ !
$ ! install snmp extension subagents
$ !
$ install_subagents:
$     image = f$edit("sys$system:tcpip$chess_subagent.exe","upcase")
$     call install_image 'image' ""
$ !
$ ! completed installation of snmp extension subagents
$ !
$ exit:
$     exit $status .or. %x10000000
$ !
$ ! install sub-agent image (p1 = image, p2 = privileges)
$ !
$ install_image: subroutine
$     set noon
$     status = 1
$
$     p1 = p1 - f$parse(p1,,,"version")
$
$     if f$search(p1) .eqs. ""
$     then
$	  status = 2
$	  write sys$output "%TCPIP-E-NOIMAGE, cannot find image file ''p1'"
$     else
$	  if .not. f$file_attributes(p1,"known")
$	  then
$	      if p2 .eqs. ""
$	      then
$		  install create 'p1' /header_resident/open/shared
$	      else
$		  install create 'p1' /header_resident/open/shared/privileged=('p2')
$	      endif
$
$	      status = $status
$	      if status
$	      then
$		  call log_info "%TCPIP-I-INFO, image ''p1' installed"
$	      else
$		  write sys$output "%TCPIP-E-IMGINSTERR, error installing ''p1'"
$	      endif
$	  endif
$     endif
$
$     exit status .or. %x10000000
$     endsubroutine
$ !
$ ! log informational message (p1 = message text)
$ !
$ log_info: subroutine
$     set noon
$
$     if (tcpip$param_loginfo .eqs. "") .or. (tcpip$param_loginfo .nes. "QUIET")
$     then
$	  write sys$output "''p1'"
$     endif
$
$     exit 1
$     endsubroutine